悬赏500无忧币：解决PE下，用批处理“获取X盘的文件大小”出错的问题。谢谢

yyz2191958

完美解决：
@set @x=1 /* &@echo off &::【代码（最前）和（最后）好像不能有字符。（z.toFixed(3)————3位小数）】
if "%~1"=="" exit /b 3
if not exist %1 exit /b 3
set "v=" &set "v=%~1"
set "q=0"
dir /ad %1 >nul 2>&1
if %errorlevel% equ 0 (set "q=1") else if exist "%v%" (for %%v in ("%v%") do set "v=%%~zv") else set "v=%v:,=%"
cscript /nologo /e:jscript "%~f0" "%v%" %q%
pause>nul 2>nul&exit/b */
n=0, v=WSH.arguments, q=v(1);
if (q==1) { z=WSH.createObject('scripting.fileSystemObject').getFolder(v(0)).size }
else z=+v(0);
while (z/1024>=1) {z/=1024; n++; if (n==6) break;}
z=z.toFixed(3)+[' 字节',' KB',' MB',' GB',' TB',' PB',' EB'][n];
WSH.echo(z), WSH.quit();

===============================================
原来的问题：
悬赏500无忧币：解决PE下，用批处理“获取X盘的文件大小”出错的问题。谢谢
*******************************************************************************
由于悬赏的无忧币，如果问题没有解决，不能够返回。由此，这里悬赏1无忧币，一旦问题解决，我会编辑为悬赏500无忧币给你。谢谢
*******************************************************************************
已有批处理“文件、文件夹（拖到图标）显示大小（有小数）.bat”
=====================================================
@set @x=1 /* &@echo off  &::【代码（最前）和（最后）好像不能有字符。（z.toFixed(2)————两位小数）】
set "v=" &set "v=%1"
if not defined v (exit/b) else (set "q=0" &set v=%v:"=%)
if exist "%v%"\ (set "q=1") else if exist "%v%" (for %%v in ("%v%") do set "v=%%~zv") else set "v=%v:,=%"
cscript /nologo /e:jscript "%~f0" "%v%" %q%
pause>nul 2>nul&exit/b */
n=0, v=WSH.arguments, q=v(1);
if (q==1) { z=WSH.createObject('scripting.fileSystemObject').getFolder(v(0)).size }
else z=+v(0);
while (z/1024>=1) {z/=1024; n++; if (n==6) break;}
z=z.toFixed(2)+[' 字节',' KB',' MB',' GB',' TB',' PB',' EB'][n];
WSH.echo(z), WSH.quit();
=====================================================
目的：将“文件 或 文件夹”，拖到bat的图标上，就在窗口显示文件（文件夹）的大小（能够根据数数值的大小，自动显示为：字节、KB、MB、GB、TB、PB、EB）
=====================================================
目前情况：在 10 PE下（2013koko制作的：Win10PEx64_10586_网络版）
http://bbs.wuyou.net/forum.php?mod=viewthread&tid=435502
将“文件 或 文件夹”拖到bat的图标上，拖c、d盘上的“文件 或 文件夹”没有问题。将X盘“文件 或 文件夹”拖到bat的图标上，文件夹没有问题，文件就提示：路径未找到。
http://bbs.wuyou.net/forum.php?mod=viewthread&tid=444771&extra=
=====================================================
需要达到目的：
将“文件 或 文件夹”，拖到bat的图标上就在窗口显示文件（文件夹）的大小（能够根据数数值的大小，自动显示为：字节、KB、MB、GB、TB、PB、EB）（我的PE下 和 正常系统中都正常）（修改原有bat，或者自己写都行）

hua_wuxin

if not defined v (exit/b) else (set "q=0" &set v=%v:"=%)
dir /ad %1 >nul 2>&1
if %errorlevel% equ 0 (set "q=1") else if exist "%v%" (for %%v in ("%v%") do set "v=%%~zv") else set "v=%v:,=%"
cscript /nologo /e:jscript "%~f0" "%v%" %q%

事后更正：之前括号处理仍有问题，加粗红字为修正。推荐24楼改法。
另外注意%v%里含有括号时，例如“X:\Program Files (x86)”，批处理会出错，需要替换为^(和^)。
set "v=" &set "v=%1"
if defined v set v=%v:(=^(% &set v=%v:)=^)%
if not defined v (exit/b) else (set "q=0" &set v=%v:"=%)

yyz2191958

占楼备用

yyz2191958

martin313 发表于 2025-2-18 09:00
@echo off
setlocal enabledelayedexpansion

'powershell' 不是内部或外部命令，也不是可运行的程序
或批处理文件。
'powershell' 不是内部或外部命令，也不是可运行的程序
或批处理文件。
大小:
请按任意键继续. . .

忧心的启

用个对比文件不行吗？

yyz2191958

忧心的启 发表于 2025-2-18 09:21
用个对比文件不行吗？

对比文件有什么用？

yyz2191958

martin313 发表于 2025-2-18 10:10
这个批处理中，@x=1 是干啥的？会不会这个影响到了X盘的路径问题

我不知道，这些代码是 “批处理之家” 得到的

你说的是有可能的

yyz2191958

martin313 发表于 2025-2-18 10:10
这个批处理中，@x=1 是干啥的？会不会这个影响到了X盘的路径问题

将@x=1弄成@M=1，情况还是一样

yyz2191958

hua_wuxin 发表于 2025-2-18 10:32
if not defined v (exit/b) else (set "q=0" &set v=%v:"=%)
dir /ad %1 >nul 2>&1
if %errorlevel% equ  ...

我试一试先 谢谢

yyz2191958

hua_wuxin 发表于 2025-2-18 10:32
if not defined v (exit/b) else (set "q=0" &set v=%v:"=%)
dir /ad %1 >nul 2>&1
if %errorlevel% equ  ...

是完整代码吗？我拖到图标无显示

hua_wuxin

yyz2191958 发表于 2025-2-18 10:49
是完整代码吗？我拖到图标无显示

不是
红字是改动的地方 黑字是你原文识别改动的位置用

yyz2191958

martin313 发表于 2025-2-18 10:55
X盘的系统文件或文件夹，无法计算大小，我猜是因为PE运行情形下，批处理没权限的原因吧

文件夹没有问题，就是文件不行

yyz2191958

hua_wuxin 发表于 2025-2-18 10:57
不是
红字是改动的地方 黑字是你原文识别改动的位置用

好像可以了，我慢慢认真测试先，非常感谢

hua_wuxin

之前括号的处理还是有点问题，%1为空（例如直接双击批处理）时会报错。推荐如下改动：
@set @x=1 /* &@echo off  &::【代码（最前）和（最后）好像不能有字符。（z.toFixed(2)————两位小数）】
if "%~1"=="" exit /b 3
if not exist %1 exit /b 3
set "v=" &set "v=%~1"
set "q=0"
dir /ad %1 >nul 2>&1
if %errorlevel% equ 0 (set "q=1") else if exist "%v%" (for %%v in ("%v%") do set "v=%%~zv") else set "v=%v:,=%"
cscript /nologo /e:jscript "%~f0" "%v%" %q%

（以下未动，略）

yyz2191958

hua_wuxin 发表于 2025-2-18 11:27
之前括号的处理还是有点问题，%1为空（例如直接双击批处理）时会报错。推荐如下改动：
@set @x=1 /* &@ech ...

谢谢 我再试一试

baikunlun

hua_wuxin 发表于 2025-2-18 08:22
if not defined v (exit/b) else (set "q=0" &set v=%v:"=%)
dir /ad %1 >nul 2>&1
if %errorlevel% equ  ...

看来是 目录的判断方式上有点问题，遇到X盘时
if exsit  "PATH"\

yyz2191958

martin313 发表于 2025-2-18 12:36
楼主还没回答我的问题：这用来干嘛呢？

快捷方式放到 “发送到”，我喜欢自动：字节、KB、MB、GB ... ...，还能自定义小数点位数

ppll2030

哎呀。来晚了。
看koko的pe写着支持vbs，用VBS写了一个，也发上来留个记录吧

1. Set fso = CreateObject("Scripting.FileSystemObject")
   
2. obj = WScript.Arguments(0)
   
3. 
   
4. If fso.FileExists(obj) Then
   
5.     fileSize = fso.GetFile(obj).Size
   
6.     fileConvertSize = ConvertSize(fileSize)
   
7.     WScript.Echo "文件大小: " & fileConvertSize
   
8. Else
   
9.     folderSize = GetFolderSize(obj)
   
10.     folderConvertSize = ConvertSize(folderSize)
    
11.     WScript.Echo "文件夹大小: " & folderConvertSize
    
12. End If
    
13. 
    
14. Function GetFolderSize(folderPath)
    
15.     totalSize = 0
    
16.     Set folder = fso.GetFolder(folderPath)
    
17.     For Each subFolder In folder.SubFolders
    
18.         totalSize = totalSize + GetFolderSize(subFolder.Path)
    
19.     Next
    
20.     For Each file In folder.Files
    
21.         totalSize = totalSize + file.Size
    
22.     Next
    
23.     GetFolderSize = totalSize
    
24. End Function
    
25. 
    
26. Function ConvertSize(Size)
    
27. units = Array("字节", "KB", "MB", "GB", "TB", "PB", "EB")
    
28. i = 0
    
29. While Size >= 1024 And i < UBound(units)
    
30.     Size = Size / 1024
    
31.     i = i + 1
    
32. Wend
    
33. ConvertSize = Round(Size, 2) & " " & units(i)
    
34. End Function

复制代码